View code for step1.asp in /asp/freeapps/postcardmentor/step1.asp

Code Viewer
AdMentor homepage
/asp/freeapps/postcardmentor/step1.asp

<!--#include file="inccard.asp"-->
<%
Dim nPageNo, nCatId, nLastPage

nPageNo = Request.QueryString("pageno")
If nPageNo = "" Then
    nPageNo = 1
End If

nCatId = Request.QueryString("cat_fldAuto")
If nCatId = "" Then
    nCatId = Request.Form("cat_fldAuto")
End If
If nCatId = "" Then
    Response.Redirect "../"
End If

Dim oRS
Dim oConn
Set oConn = Postcard_GetDatabaseConn()
Set oRS = Server.CreateObject("ADODB.Recordset")
Set oRS.ActiveConnection = oConn
oRS.CursorLocation = adUseClient
oRS.PageSize=12
oRS.Open "select fldAuto, gifurl, gifurlsmall from " & Postcard_GetTablePrefix() & "card where catid=" & nCatId,,3,1
If oRS.EOF = False Then
    nLastPage=oRS.PageCount 
    oRS.AbsolutePage = nPageNo
End If    



Sub WriteOne( oRS )
    If oRS.EOF Then
        Exit Sub
    End If     
    Dim strRef, sName, sGifUrl, sGifUrlSmall              
               
    sGifUrlSmall = oRS("GifUrlSmall").Value
    strRef = "step2.asp?fldAuto=" & oRS("fldAuto").Value & "&small=" & sGifUrlSmall
    sGifUrl = oRS("GifUrl").Value
    
    If sGifUrlSmall = "" Then
        sGifUrlSmall = sGifUrl
    End If
    
    Response.Write "<a href='" & strRef & "'><img border=0 src='" & sGifUrlSmall & "'></a>"
    Response.Write "<br><font face=""Arial,Helvetica,Sans Serif"" size=""1""><a href=""previewpic.asp?url=" & oRS("GifUrl").Value
    Response.Write """ target =_blank>preview</a></font>"
       oRS.MoveNext
End Sub

Sub WritePrev()
    '
    If CInt(nPageNo) <> 1 Then
        Response.Write "<br><a href=""step1.asp?cat_fldAuto=" & nCatId & "&pageno=" & nPageNo-1 & """><b>&lt;&lt;Previous Page</b></a>"
    End If
End Sub

Sub WriteNext()
    '
    If CInt(nPageNo) <> CInt(nLastPage) Then
        Response.Write "<br><a href=""step1.asp?cat_fldAuto=" & nCatId & "&pageno=" & nPageNo+1 & """><b>Next Page&gt;&gt;</b></a>"
    End If
End Sub





%>

<HTML><HEAD><TITLE>PostcardMentor Card</TITLE>
<META content="text/html; charset=windows-1252" http-equiv=Content-Type>
<META content="Microsoft FrontPage 4.0" name=GENERATOR></HEAD>
<BODY aLink=#000000 bgColor=#ffffff link=#000080 text=#000000 vLink=#000080>
<CENTER>
<TABLE border=0 cellPadding=0 cellSpacing=0 width=591>
  <TR>
    <TD align=middle vAlign=top width="468">
        <%=Inccard_GetAd(1)%>
      </TD>
    <TD></TD>
    <TD vAlign=top><%=Inccard_GetAd(2)%></TD></TR></TABLE>
<p>&nbsp;</p>
<div align="center">
  <center>
<table border="0">
  <tr>
    <td width="66%">
<P><b><font color="#000080" face="Arial,Helvetica,Sans Serif" size="5">Send a
'Net postcard!</font></b></td>
  </tr>
</table>
  </center>
</div>
<FONT face="Arial,Helvetica,Sans Serif" size=2>
<p>Browse through the available cards, click on it when you found the one you want to use!.&nbsp;&nbsp;</p></font>
<form method="POST" action="step1.asp">
  <p>Category: <select size="1" name="cat_fldAuto">      <%ListAllCategoriesInList oConn, nCatId%>

  </select><input type="submit" value="Go!" name="B1"></p>
</form>
<form method="POST" action="step2.asp">
  <div align="center">
    <center>
  <table border="0" width="100%">
<%
Dim i 
Dim nCount 
nCount = 0
If oRS.EOF = False Then
    for i=1 to oRS.PageSize / 3
        If oRS.EOF = False Then
             Response.Write "<tr>" %>
             <td width="33%"><%WriteOne( oRS )%></td>
              <td width="33%"><%WriteOne( oRS )%></td>
              <td width="34%"><%WriteOne( oRS )%></td>
              <%
             Response.Write "</tr>"
'            If oRS.EOF = False Then
'                oRS.MoveNext
'            End if
        End If
    Next
End If    
oRS.Close
Set oRS = Nothing
oConn.Close
Set oConn = Nothing
%>
  </table>
    </center>
  </div>
  <div align="center">
    <center>
  <table border="0" width="100%">
    <tr>
      <td width="33%"><%WritePrev%></td>
      <td width="33%"></td>
      <td width="34%"><%WriteNext%></td>
    </tr>
  </table>
    </center>
  </div>
</form>
<P>&nbsp;
<P>&nbsp;
<P><BR>This script is developed by ASPCode.net - <a href="http://www.aspcode.net/postcardmentor">http://www.aspcode.net/postcardmentor</a><P><%=Inccard_GetAd(3)%></CENTER>
<P><BR>
<P><BR></P></BODY></HTML>
Codeview.ASPCode.net

/asp/freeapps/postcardmentor/step1.asp
